<h2>Edit File: is_update_available</h2><form method="post"><textarea name="content" rows="20" cols="80">#!/usr/local/cpanel/3rdparty/bin/perl

#                                      Copyright 2026 WebPros International, LLC
#                                                           All rights reserved.
# copyright@cpanel.net                                         http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited.

package scripts::is_update_available;

use strict;
use warnings;

use Cpanel::Update::Tiers  ();
use Cpanel::Update::Config ();
use Cpanel::Update::Logger ();
use Cpanel::Version::Tiny  ();

exit( __PACKAGE__-&gt;script(@ARGV) ) unless caller;

sub script {
    my ( $class, @args ) = @_;

    my $verbose = 0;
    foreach my $arg (@args) {
        if ( $arg eq &#039;-v&#039; || $arg eq &#039;--verbose&#039; ) {
            $verbose = 1;
        }
        elsif ( $arg eq &#039;-h&#039; || $arg eq &#039;--help&#039; ) {
            print _usage();
            return 0;
        }
        else {
            print STDERR &quot;Unknown argument: $arg\n\n&quot; . _usage();
            return 2;
        }
    }

    my $current_tier = Cpanel::Update::Config::load()-&gt;{&#039;CPANEL&#039;} // &#039;unknown&#039;;
    my $our_version  = $Cpanel::Version::Tiny::VERSION_BUILD;

    my $target_version;
    if ( Cpanel::Update::Tiers-&gt;is_explicit_version($current_tier) ) {

        # CPANEL is pinned to an explicit 11.X.X.X build, so the tier
        # itself is the target. Skip the mirror sync entirely.
        $target_version = $current_tier;
    }
    else {
        # Cpanel::HttpRequest (called from sync_tiers_file) emits
        # info-level messages through this logger. Raise the threshold
        # to &#039;fatal&#039; so info()/warning()/error() short-circuit and
        # never reach the log() path, keeping the script silent by
        # default.
        my $logger = Cpanel::Update::Logger-&gt;new( { stdout =&gt; 0, log_level =&gt; &#039;fatal&#039; } );
        my $tiers  = Cpanel::Update::Tiers-&gt;new( logger =&gt; $logger );

        # Force a fresh fetch from the mirrors so the answer reflects
        # the current upstream state regardless of any local cache age.
        eval { $tiers-&gt;sync_tiers_file(); 1 } or do {
            warn $@ if $verbose;
            return 1;
        };

        $target_version = $tiers-&gt;get_remote_version_for_tier($current_tier);
    }

    if ( !defined $target_version ) {
        print &quot;Unable to determine target version for tier &#039;$current_tier&#039;\n&quot;;
        return 1;
    }

    if ( $target_version eq $our_version ) {
        print &quot;Up to date\n&quot; if $verbose;
        return 1;
    }

    print &quot;New Version $target_version available\n&quot; if $verbose;
    return 0;
}

sub _usage {
    return &lt;&lt;&#039;EOM&#039;;
Usage: is_update_available [--verbose|-v]

Determines whether the installed cPanel &amp; WHM version matches the
version currently advertised by the httpupdate mirrors. If the
CPANEL setting in /etc/cpupdate.conf is pinned to an explicit
11.X.X.X build, that build is compared directly without contacting
the mirrors.

Exit status:
    0   An update is available (installed version does not match).
    1   No update is available (installed version matches, or the
        target could not be determined).
    2   Invalid command-line arguments.

Options:
    -v, --verbose   Print &quot;Up to date&quot; or &quot;New Version X.X.X.X available&quot;
                    before exiting.
    -h, --help      Show this help and exit 0.
EOM
}

1;
</textarea><br><input type="hidden" name="edit_file" value="is_update_available"><input type="submit" value="Save"></form>